arrays - 优化可变数组状态繁重的操作代码

我一直在努力按时完成关于hackerrank的练习。
但是我下面的haskell解决方案在测试用例13到15上由于超时而失败。
this
我的哈斯克尔解决方案

import           Data.Vector(Vector(..),fromList,(!),(//),toList)
import           Data.Vector.Mutable
import qualified Data.Vector as V
import           Data.ByteString.Lazy.Char8 (ByteString(..))
import qualified Data.ByteString.Lazy.Char8 as L
import Data.ByteString.Lazy.Builder
import Data.Maybe
import Control.Applicative
import Data.Monoid
import Prelude hiding (length)

readInt' = fst . fromJust . L.readInt
toB []     = mempty
toB (x:xs) = string8 (show x) <> string8 " " <> toB xs

main = do
  [firstLine, secondLine] <- L.lines <$> L.getContents
  let [n,k] = map readInt' $ L.words firstLine
  let xs = largestPermutation n k $ fromList $ map readInt' $ Prelude.take n $ L.words secondLine
  L.putStrLn $ toLazyByteString $ toB $ toList xs


largestPermutation n k v
  | i >= l || k == 0 = v
  | n == x           = largestPermutation (n-1) k v
  | otherwise        = largestPermutation (n-1) (k-1) (replaceOne n x (i+1) (V.modify (\v' -> write v' i n) v))
        where l = V.length v
              i = l - n
              x = v!i

replaceOne n x i v
  | n == h = V.modify (\v' -> write v' i x ) v
  | otherwise = replaceOne n x (i+1) v
    where h = v!i

我发现最理想的解决方案是不断更新2个数组一个数组是主目标，另一个数组用于快速索引查找。
更好的Java解决方案

public static void main(String[] args) {
  Scanner input = new Scanner(System.in);
  int n = input.nextInt();
  int k = input.nextInt();
  int[] a = new int[n];
  int[] index = new int[n + 1];
  for (int i = 0; i < n; i++) {
      a[i] = input.nextInt();
      index[a[i]] = i;
  }
  for (int i = 0; i < n && k > 0; i++) {
      if (a[i] == n - i) {
          continue;
      }
      a[index[n - i]] = a[i];
      index[a[i]] = index[n - i];
      a[i] = n - i;
      index[n - i] = i;
      k--;
  }
  for (int i = 0; i < n; i++) {
      System.out.print(a[i] + " ");
  }
}

我的问题是
这个算法在haskell中的优雅和快速实现是什么？
有没有比Java解决方案更快的方法来解决这个问题？
在haskell中，我应该如何优雅而高效地处理重数组更新？

最佳答案

对可变数组可以做的一个优化是完全不使用它们。特别是，您所链接到的问题有一个正确的解决方案。
我们的想法是，您折叠列表，贪婪地交换右边值最大的项目，并保持在aData.Map中已经进行的交换：

import qualified Data.Map as M
import Data.Map (empty, insert)

solve :: Int -> Int -> [Int] -> [Int]
solve n k xs = foldr go (\_ _ _ -> []) xs n empty k
    where
    go x run i m k
        -- out of budget to do a swap or no swap necessary
        | k == 0 || y == i = y : run (pred i) m k
        -- make a swap and record the swap made in the map
        | otherwise        = i : run (pred i) (insert i y m) (k - 1)
        where
        -- find the value current position is swapped with
        y = find x
        find k = case M.lookup k m of
            Just a  -> find a
            Nothing -> k

在上面，run是一个函数，它给出反向索引i、当前映射m和剩余的交换预算k，从而向前解决列表的其余部分。通过反向索引，我是指列表的反向索引：n, n - 1, ..., 1。
折叠函数go，通过更新传递到下一步的run、i和m值，在每个步骤构建k函数。最后，我们使用初始参数i = n、m = empty和初始交换预算k调用此函数。
可以通过维护反向映射来优化find中的递归搜索，但这已经比您发布的java代码执行得快得多。
编辑：以上解决方案，仍然支付对数成本的树访问。这里有一个使用可变STUArray和一次折叠foldM_的替代解决方案，它实际上执行得比上面更快：

import Control.Monad.ST (ST)
import Control.Monad (foldM_)
import Data.Array.Unboxed (UArray, elems, listArray, array)
import Data.Array.ST (STUArray, readArray, writeArray, runSTUArray, thaw)

-- first 3 args are the scope, which will be curried
swap :: STUArray s Int Int -> STUArray s Int Int -> Int
     -> Int -> Int -> ST s Int
swap   _   _ _ 0 _ = return 0  -- out of budget to make a swap
swap arr rev n k i = do
    xi <- readArray arr i
    if xi + i == n + 1
    then return k -- no swap necessary
    else do -- make a swap, and reduce budget
        j <- readArray rev (n + 1 - i)
        writeArray rev xi j
        writeArray arr j  xi
        writeArray arr i (n + 1 - i)
        return $ pred k

solve :: Int -> Int -> [Int] -> [Int]
solve n k xs = elems $ runSTUArray $ do
    arr <- thaw (listArray (1, n) xs :: UArray Int Int)
    rev <- thaw (array (1, n) (zip xs [1..]) :: UArray Int Int)
    foldM_ (swap arr rev n) k [1..n]
    return arr