macos - 连续的 sys_write 系统调用没有按预期工作，OS X 上的 NASM 错误？

我正在尝试使用 NASM 学习 MacOS 程序集，但我无法让一个简单的程序工作。我正在尝试“Hello, World”的变体，其中两个词由宏独立调用。我的源代码如下所示:

%macro printString 2
    mov     rax, 0x2000004 ; write
    mov     rdi, 1 ; stdout
    mov     rsi, %1
    mov     rdx, %2
    syscall
%endmacro

global start

section .text

start:
    printString str1,str1.len

    printString str2,str2.len

    mov     rax, 0x2000001 ; exit
    mov     rdi, 0
    syscall


section .data

str1:   db      "Hello,",10,
.len:  equ       $ - str1

str2:   db      "world",10
.len:  equ       $ - str2

预期的结果应该是:

$./hw
Hello,
World
$

相反，我得到:

$./hw
Hello,
$

我错过了什么？我如何解决它？

编辑 :我正在使用以下命令编译和运行:

/usr/local/bin/nasm -f macho64 hw.asm
ld -macosx_version_min 10.7.0 -lSystem -o hw hw.o
./hw

最佳答案

NASM 2.11.08 和 2.13.02+ 有 macho64 输出的错误。你所观察到的似乎是我最近在使用绝对引用时在 2.13.02+ 中看到的。最终链接的程序应用了不正确的修正，因此对 str2 的引用不正确。不正确的修正导致我们打印出不是 str2 的内存。

NASM 在他们的系统中有一个关于这个问题的 bug report。我根据问题中的代码添加了此失败的具体示例。希望 NASM 开发人员能够重现失败并创建修复程序。

更新 :截至 2018 年 6 月，我认为 NASM 中有足够多的重复出现的错误和回归，因此我不建议在这个时间点使用 NASM 进行 Macho-64 开发。

我对 Macho-64 开发的另一个建议是使用 RIP 相对寻址而不是绝对寻址。 RIP 相对寻址是更高版本 MacOS 上 64 位程序的默认设置。

在 NASM 中，您可以使用文件中的 default rel 指令将默认地址从绝对地址更改为 RIP 相对地址。为此，在尝试将变量的地址移动到寄存器时，您必须从使用 mov register, variable 更改为 lea register, [variable]。您修改后的代码可能如下所示:

default rel

%macro printString 2
    mov     rax, 0x2000004 ; write
    mov     rdi, 1 ; stdout
    lea     rsi, [%1]
    mov     rdx, %2
    syscall
%endmacro

global start

section .text

start:
    printString str1,str1.len

    printString str2,str2.len

    mov     rax, 0x2000001 ; exit
    mov     rdi, 0
    syscall


section .data

str1:   db      "Hello,",10
.len:  equ       $ - str1

str2:   db      "world",10
.len:  equ       $ - str2

关于macos - 连续的 sys_write 系统调用没有按预期工作，OS X 上的 NASM 错误？，我们在Stack Overflow上找到一个类似的问题：https://stackoverflow.com/questions/49224997/